//+------------------------------------------------------------------+
//|                                                      ILRS_MA.mq4 |
//|                               Copyright © 2013, Gehtsoft USA LLC |
//|                                            http://fxcodebase.com |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2013, Gehtsoft USA LLC"
#property link      "http://fxcodebase.com"

#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 Yellow

extern int Length=20;
extern int Price=0;      // Applied price
                         // 0 - Close
                         // 1 - Open
                         // 2 - High
                         // 3 - Low
                         // 4 - Median
                         // 5 - Typical
                         // 6 - Weighted  

double ILRS[];
double Pr[];
double sum, sum2;

int init()
{
 IndicatorShortName("Integral of Linear Regression Slope Moving Average");
 IndicatorDigits(Digits);
 SetIndexStyle(0,DRAW_LINE);
 SetIndexBuffer(0,ILRS);
 SetIndexStyle(1,DRAW_NONE);
 SetIndexBuffer(1,Pr);

 sum=Length*(Length-1)/2;
 sum2=(Length-1)*Length*(2*Length-1)/6; 
 return(0);
}

int deinit()
{

 return(0);
}

int start()
{
 if(Bars<=Length) return(0);
 int ExtCountedBars=IndicatorCounted();
 if (ExtCountedBars<0) return(-1);
 int limit=Bars-2;
 if(ExtCountedBars>2) limit=Bars-ExtCountedBars-1;
 int pos;
 pos=limit;
 while(pos>=0)
 {
  Pr[pos]=iMA(NULL, 0, 1, 0, MODE_SMA, Price, pos);
  pos--;
 } 
 
 double sum1, sumy;
 double num1, num2;
 double slope;
 int i;
 pos=limit;
 while(pos>=0)
 {
  sum1=0;
  sumy=0;
  for (i=0;i<Length;i++)
  {
   sum1+=Pr[pos+i]*i;
   sumy+=Pr[pos+i];
  }
  num1=sum1*Length-sum*sumy;
  num2=sum*sum-sum2*Length;
  if (num2!=0)
  {
   slope=num1/num2;
  }
  else
  {
   slope=0;
  }
  ILRS[pos]=iMA(NULL, 0, Length, 0, MODE_SMA, Price, pos)+slope;
  pos--;
 }  
 
 return(0);
}